Взять информацию из буфера
Подскажите, пожалуйста, на примере как получить переменную из буфера, а именно "oszone.net":
Код:
echo off
curl http://favicon.yandex.net/favicon/oszone.net/ -o "oszone.net.png"
exit
т.е. я копирую oszone.net в буфер и при запуске bat она занимает свое место. |
Код:
:: На powershell
@echo off
powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()">"file.txt"
exit
Код:
:: На javascript
@echo off
call :# "file.txt"
exit
:#
mshta "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();">"%~1"
exit /b
Код:
:: На Autoit
@echo off
Bufer_v.exe "file.txt"
exit
Файл 153025
в переменную
Код:
:: На powershell
@echo off
for /f "delims=" %%a in ('powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()"') do echo %%a
pause
Код:
:: На javascript
@echo off
for /f "delims=" %%a in (
'mshta "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();"'
) do echo %%a
pause
Код:
:: На Autoit
@echo off
Bufer_v.exe $& <$ set /p z=& del $
echo %z%
pause
|
Цитата:
Цитата alpap
:: На powershell
@echo off
powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()">"file.txt"
exit »
|
Это я находил в поиске. Я не знаю, как это применить к решению задачи. |
добавил выше - в переменную
|
А как эту переменную скормить curl??
|
Цитата:
Цитата Sisin
А как эту переменную скормить curl?? »
|
Для этого было бы желательно понять, в каком месте в командной строке curl.exe Вы планируете её использовать. Предположим, что у Вас есть такая переменная, назовём её, допустим, sVar. Как будет выглядеть командная строка curl.exe с нею?
Где находится:
? |
Например:
Код:
@echo off
for /f "delims=" %%a in ('powershell -sta /nologo /noprofile /command "Add-Type -AssemblyName System.Windows.Forms;[Windows.Forms.Clipboard]::GetText()"') do set sVar=%%a
if defined sVar curl.exe http://favicon.yandex.net/favicon/%sVar%/ -o "%sVar%.png"
или:
Код:
@echo off
for /f "usebackq delims=" %%a in (
`mshta.exe "javascript:var x=clipboardData.getData('text');if(x)new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(x);close();"`
) do set sVar=%%a
if defined sVar curl.exe http://favicon.yandex.net/favicon/%sVar%/ -o "%sVar%.png"
|
Время: 23:08.
© OSzone.net 2001-
