Поиск файлов с определённым именем и расширением с указанием расположения.
Здравствуйте!
Возникла следующая задача: найти на всех дисках файлы с конкретным названием определённого расширения (.hta) и записать результаты в текстовый файл, с указанием расположения файла и сортировкой по дате - от старых к новым (или от новых к старым, не принципиально, важна лишь сортировка по дате\времени). Понимаю, что многого прошу, но обращаюсь за помощью, т.к. по отдельности часть задач я ещё могу сделать, а вот всё это реализовать в одном файле не получается.
Помогите, пожалуйста!
|
Сохраните в Windows-кодировке 1251, если в имени файла есть кириллица
Код:
@Echo Off
chcp 1251 >nul
Set "FName=Хливкие шорьки.hta"
Set "Log=%Tmp%\%~nx0.log"
FOR /F "usebackq tokens=1,*" %%c IN (`fsutil fsinfo drives`) DO Set "AllD=%%d"
Del "%Log%" 2>nul
Del "%Log%.tmp" 2>nul
FOR %%d IN (%AllD%) DO FOR /F "usebackq delims=" %%f IN (`dir "%%d%FName%" /B /A:-D /S 2^>nul`) DO Call :LogFile "%%~tf" "%%f"
If Exist "%Log%.tmp" (
FOR /F "usebackq delims=" %%s IN (`more "%Log%.tmp"^|Sort`) DO Echo %%s>>"%Log%"
Del "%Log%.tmp" 2>nul
) Else (
Echo Файл "%FName%" не найден>"%Log%"
)
start "s" notepad.exe "%Log%"
GoTo :Eof
:LogFile
FOR /F "tokens=1,2,3,* delims=./ " %%i IN ("%~1") DO Echo %%k %%j %%i %%l %2 >>"%Log%.tmp"
GoTo :Eof
|
Цитата:
Цитата megaloman
Сохраните в Windows-кодировке 1251 чтобы результат корректно отображался в notepad »
|
Это неправильные пчёлы. |
Iska, Я у Вас многому научился. Натыкайте меня носом. :cry:
|
Мне кажется, что будет правильнее перечислить редакторы, которые «умеют» OEM/866.
|
Iska, Сложно сказать, как правильнее в конкретном контексте. Просили текстовый файл. Мне удобнее пользоваться фаром, кому-то удобнее получать результат в стандартном нотепаде без привлечения другого софта.
|
Iska,
Цитата:
Цитата Iska
Мне кажется, что будет правильнее перечислить редакторы, которые «умеют» OEM/866. »
|
раз - notepad со шрифтом terminal ;)
Цитата:
Цитата megaloman
Мне удобнее пользоваться фаром »
|
значит ты должен предпочитать CP866 и рекомендовать его другим!
|
y--, Авторитетные источники утверждают, что программы пишутся для пользователей. В данном случае, пытаюсь угадать, что удобно пользователю, а не мне.
|
Время: 22:29.
© OSzone.net 2001-
