[решено] Удаление папок больше n штук - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] Удаление папок больше n штук (http://forum.oszone.net/showthread.php?t=296673)

thehisteam

10-03-2015 12:23 2480919

Удаление папок больше n штук

Здравствуйте! Подскажите пожалуйста как реализовать скрипт:
Есть несколько каталогов с бэкапами, в которых ежедневно создаются папки с текущей датой 2015-03-11, где собственно и хранятся бэкапы. Как ограничить количество папок с датами 7 шт? Чтобы при превышении количества папок старые удалялись. Спасибо)

thehisteam

10-03-2015 12:31 2480922

Нашел готовый скрипт для моей задачи. Большое спасибо Iska
Только подскажите пожалуйста как добавить несколько директорий в скрипт, для каждой добавлять переменную и сам скрипт?

Код:

@echo off

setlocal enableextensions enabledelayedexpansion



set sFolder=C:\Documents and Settings\User\Мои документы\Мои рисунки\PicPic

set /a iCount = 10



for /f "skip=%iCount% usebackq delims=" %%i in (

        `dir /b /a:d /o:-d /t:w "%sFolder%"`

) do echo rd /s /q "%sFolder%\%%~i"



endlocal

exit /b 0

Iska	10-03-2015 20:30 2481093

Как-то так (не проверялось):

Скрытый текст

Код:

@echo off

setlocal enableextensions enabledelayedexpansion



set /a iCount = 10



for %%i in (

        "C:\Documents and Settings\User\Мои документы\Мои рисунки\PicPic"

        "C:\Мои проекты\001"

        "C:\Мои проекты\002"

) do (

        for /f "skip=%iCount% usebackq delims=" %%j in (

                `2^>nul dir /b /a:d /o:-d /t:w "%%~i"`

        ) do echo rd /s /q "%%~i\%%~j"

)



endlocal

exit /b 0

Для реального удаления уберите «echo».

thehisteam

11-03-2015 08:46 2481190

Iska, Спасибо огромное. Скажите пожалуйста с чего можно начать изучение скриптов (какие сайты почитать), чтобы использовать их в таких повседневных задачах?

Время: 21:19.