Открытие документа
Подскажите пожалуйста, с помощью vbs открываю текстовые файлы след.командой
Код:
Option Explicit
Const wdOpenFormatEncodedText = 5
Const msoEncodingOEMCyrillicII = 866
Dim objDocument
With WScript.CreateObject("Word.Application")
.Visible = True
Set objDocument = .Documents.Open("С:\WORK\BALANS.txt", False, False, False, "", "", False, "", "", wdOpenFormatEncodedText, msoEncodingOEMCyrillicII)
WScript.Quit 0
1.Можно в vbs сделать чтобы выводился список всех файлов в данной паке или диалоговое окно для последующего открытия в ворде?
2.Можно в vbs сделать вывод сообщения, типа:"Вопрос" с кнопками ДА и НЕТ?
Заранее спасибо. |
Цитата:
Цитата AlexVong
1.Можно в vbs сделать чтобы выводился список всех файлов в данной паке или диалоговое окно для последующего открытия в ворде? »
|
Что-то наподобие такого?
читать дальше »
Код:
Option Explicit
Const wdOpenFormatEncodedText = 5
Const msoEncodingOEMCyrillicII = 866
Const msoFileDialogFilePicker = 3
Const msoFileDialogViewList = 1
Dim collPaths
Dim strPath
With WScript.CreateObject("Word.Application")
.Visible = True
With .FileDialog(msoFileDialogFilePicker)
.AllowMultiSelect = True
.InitialView = msoFileDialogViewList
.Title = "Укажите файлы для обработки"
.ButtonName = "Открыть"
.InitialFileName = "c:\Windows\System32\"
With .Filters
.Clear
.Add "Текстовые файлы", "*.txt"
.Add "Все файлы", "*.*"
End With
If .Show Then
Set collPaths = .SelectedItems
Else
Set collPaths = Nothing
End If
End With
If Not collPaths Is Nothing Then
For Each strPath In collPaths
With .Documents.Open(strPath, False,,,,,,,, wdOpenFormatEncodedText, msoEncodingOEMCyrillicII)
' Например…
WScript.Echo "Путь к документу: ", .FullName
WScript.Echo "Количество абзацев:", .Paragraphs.Count
WScript.Echo
.Close
End With
Next
End If
.Quit
End With
WScript.Quit 0
Цитата:
Цитата AlexVong
2.Можно в vbs сделать вывод сообщения, типа:"Вопрос" с кнопками ДА и НЕТ? »
|
MsgBox(…):
читать дальше »
Код:
Select Case MsgBox("Вопрос", vbYesNo + vbQuestion + vbDefaultButton1, "Заголовок")
Case vbYes
WScript.Echo "Да"
Case vbNo
WScript.Echo "Нет"
Case Else
WScript.Echo "???"
End Select
|
Время: 17:22.
© OSzone.net 2001-
